Windows Tools

Synios-Sicherung

Synios ist ein Archiv-System welches gescannte Dokumente/Akten strukturiert in durchnummerierte Ordner in CD Größe ablegt. Informationen zum Dokument werden nach dem Scanvorgang in eine DAT-Datei abgelegt die in der Ordnerstruktur liegt integriert. Somit ändert sich die DAT-Datei bis der Ordner eine CD Größe erreicht hat.
Die Sicherung der Daten ist auf CD vorgesehen.
Da CDs im Klinikumfeld nicht als Revision sicher gelten, werden die Daten auf ein revisionissicheres Medium (FastLTA) gelegt.
Jetzt zum Script. Da die Daten im aktuellem Ordner sich noch ändern, können diese nicht sofort auf ein revisionissicheres Medium gespeichert werden, sondern erst wenn alle Änderungen abgeschlossen sind.

Notwendige Vorgänge
- Sicherung des aktuellen Ordners auf ein NAS.
- Sicherung des vorherigen abgeschlossenen Ordners auf FastLTA wenn es noch nicht erstellt worden ist.
- Löschung des vorherigen Ordners vom NAS und unnötigen Speicherplatz freizugeben.


Batch

cls
@color 0A
@echo ###############################################################################
@echo #                                                         30.01.2011 M. Wulff #
@echo # Sicherung von Synius-Dateien auf Fast LTA und NAS                           #
@echo # Es darf nur der vorletzte Ordner von Synius gesichert werden!               #
@echo ############################################################################### 
@echo.
@rem !!! WICHTIG !!!  Script-Variablen
set Quelle=C:\Test_Synios\Quelle\DatenAblage\Scan
set FAST_LTA=C:\Test_Synios\FAST_LTA
set NAS=C:\Test_Synios\NAS
set Script=C:\Test_Synios\Script
@rem Schreiben der Ordner letzte zu erst in Datei ordner.txt
dir %Quelle% /AD /B /O-N > %Script%\ordner.txt
@rem FAST LTA Sicherung
for /f "tokens=1,* delims=:" %%i in ('findstr /n  $ %Script%\ordner.txt') do @(
  for /L %%a in (2,2,2) do @(
	if %%i==%%a @(
	  @rem die Variable %%j ist der vorletzte Ordner
	  echo %%j
	  if not exist %FAST_LTA%\%%j (
	    echo -- Datensicherung FAST LTA starten --
		%Script%\robocopy %Quelle%\%%j %FAST_LTA%\%%j /r:10 /w:10 /MIR
      ) else (
	    Echo Es gibt keine neue CD, der Ordner %%j besteht schon auf den Fast LTA
	  )
	  if exist %NAS%\%%j (
	    @rem altes nicht mehr benoetigten NAS-Ordner loeschen
	    rmdir /s /q %NAS%\%%j
	  )
	)
  )
)
@rem NAS Sicherung
for /f "tokens=1,* delims=:" %%i in ('findstr /n  $ %Script%\ordner.txt') do @(
  for /L %%a in (1,1,1) do @(
  	if %%i==%%a @(
	  @rem die Variable %%j ist der erste Ordner
	  echo %%j
	  %Script%\robocopy %Quelle%\%%j %NAS%\%%j /r:10 /w:10 /MIR
	)
  )
)

Download

Seitenanfang

 © 2009 M-Wulff.de